#extension GL_ARB_explicit_attrib_location : enable

// ping pong inputs
uniform sampler2DRect particles0;
uniform sampler2DRect particles1;
uniform sampler2DRect particles2;
uniform sampler2DRect particles3;

uniform sampler2DRect   u_depth;
uniform sampler2DRect   u_world;
uniform sampler2DRect   u_v4l2cam;

uniform ivec2 uFrameSize;
uniform ivec2 uDepthFrameSize;

uniform vec3 mouse;
uniform float radiusSquared;
uniform float elapsed;

uniform vec3 uHottest0;
uniform vec3 uHottest1;

in vec2 texCoordVarying;

layout(location = 0) out vec4 posOut;
layout(location = 1) out vec4 velOut;
layout(location = 2) out vec4 misOut;
layout(location = 3) out vec4 tarOut;


vec3 random3(vec3 c) {
	float j = 4096.0*sin(dot(c,vec3(17.0, 59.4, 15.0)));
	vec3 r;
	r.z = fract(512.0*j);
	j *= .125;
	r.x = fract(512.0*j);
	j *= .125;
	r.y = fract(512.0*j);
	return r-0.5;
}

/* skew constants for 3d simplex functions */
const float F3 =  0.3333333;
const float G3 =  0.1666667;

/* 3d simplex noise */
float simplex3d(vec3 p) {
	 /* 1. find current tetrahedron T and it's four vertices */
	 /* s, s+i1, s+i2, s+1.0 - absolute skewed (integer) coordinates of T vertices */
	 /* x, x1, x2, x3 - unskewed coordinates of p relative to each of T vertices*/
	 
	 /* calculate s and x */
	 vec3 s = floor(p + dot(p, vec3(F3)));
	 vec3 x = p - s + dot(s, vec3(G3));
	 
	 /* calculate i1 and i2 */
	 vec3 e = step(vec3(0.0), x - x.yzx);
	 vec3 i1 = e*(1.0 - e.zxy);
	 vec3 i2 = 1.0 - e.zxy*(1.0 - e);
	 	
	 /* x1, x2, x3 */
	 vec3 x1 = x - i1 + G3;
	 vec3 x2 = x - i2 + 2.0*G3;
	 vec3 x3 = x - 1.0 + 3.0*G3;
	 
	 /* 2. find four surflets and store them in d */
	 vec4 w, d;
	 
	 /* calculate surflet weights */
	 w.x = dot(x, x);
	 w.y = dot(x1, x1);
	 w.z = dot(x2, x2);
	 w.w = dot(x3, x3);
	 
	 /* w fades from 0.6 at the center of the surflet to 0.0 at the margin */
	 w = max(0.6 - w, 0.0);
	 
	 /* calculate surflet components */
	 d.x = dot(random3(s), x);
	 d.y = dot(random3(s + i1), x1);
	 d.z = dot(random3(s + i2), x2);
	 d.w = dot(random3(s + 1.0), x3);
	 
	 /* multiply d by w^4 */
	 w *= w;
	 w *= w;
	 d *= w;
	 
	 /* 3. return the sum of the four surflets */
	 return dot(d, vec4(52.0));
}

/* const matrices for 3d rotation */
const mat3 rot1 = mat3(-0.37, 0.36, 0.85,-0.14,-0.93, 0.34,0.92, 0.01,0.4);
const mat3 rot2 = mat3(-0.55,-0.39, 0.74, 0.33,-0.91,-0.24,0.77, 0.12,0.63);
const mat3 rot3 = mat3(-0.71, 0.52,-0.47,-0.08,-0.72,-0.68,-0.7,-0.45,0.56);

/* directional artifacts can be reduced by rotating each octave */
float simplex3d_fractal(vec3 m) {
    return   0.5333333*simplex3d(m*rot1)
			+0.2666667*simplex3d(2.0*m*rot2)
			+0.1333333*simplex3d(4.0*m*rot3)
			+0.0666667*simplex3d(8.0*m);
}

vec2 stToV4l2(vec2 v) {
  v *= 1.5;
  v.s -= 85;
  v.t -= 130;
  return v;
}

vec2 v4l2ToSt(vec2 v) {
  v.s += 85;
  v.t += 130;
  v /= 1.5;
  return v;
}

void main()
{
  vec3 pos = texture(particles0, texCoordVarying.st).xyz;
  vec3 vel = texture(particles1, texCoordVarying.st).xyz;
  vec3 misc = texture(particles2, texCoordVarying.st).xyz;
  vec4 target = texture(particles3, texCoordVarying.st).xyzw;

  vec2 v4l2st = stToV4l2(texCoordVarying.st);
  float thermo = texture2D(u_v4l2cam, v4l2st).r;

  float depth = texture(u_depth, texCoordVarying.st).x;
  vec4 ray = texture(u_world, texCoordVarying.st);

  float vValid = (depth != 0 && ray.x != 0 && ray.y != 0) ? 1 : 0;

  // if(depth < 0.012) vValid = 0;
  // if(depth > 0.04) vValid = 0;

  vec4 posWorld = vec4(1);
  posWorld.z = -depth * 65535.0; // Remap to float range.
  posWorld.x = ray.x * posWorld.z;
  posWorld.y = ray.y * posWorld.z;

  float age = misc.y;
  if(age > 1) {
    target.w = 0;
    if(vValid == 1) {
      age = 0;
    }
  }

  if(vValid == 1 && target.w == 0) {
    pos = posWorld.xyz;
    age = 0;
    target.xyz = pos;
  }
  else {
    age += 0.02;
    thermo = misc.x;
  }

  vec3 force = vec3(0,0,0);
  float th = 3.1415 * 4 * simplex3d_fractal(vec3(pos.xyz * 0.001));
  float phi = 3.1415 * simplex3d_fractal(pos.xyz * 0.002);
  force.x += cos(th) * cos(phi);
  force.y += sin(th) * cos(phi);
  force.z += sin(phi);
  force *= 100;

  if(age < 0.001) {
    target.w = 0;
    if(random3(pos).x > length(v4l2st - uHottest0.st)/100) {
      vec2 h = v4l2ToSt(uHottest1.st);
      vec4 hray = texture(u_world, h);
      float hdepth = -depth * 65535.0;
      if(hdepth == 0) hdepth = -0.01 * 65535.0;
      vec3 H = vec3(hray.xy * hdepth, hdepth);
      target.xyz = H;
      target.w = 1;
    }
    else if(random3(pos).x > length(v4l2st - uHottest1.st)/100) {
      vec2 h = v4l2ToSt(uHottest0.st);
      vec4 hray = texture(u_world, h);
      float hdepth = -depth * 65535.0;
      if(hdepth == 0) hdepth = -0.01 * 65535.0;
      vec3 H = vec3(hray.xy * hdepth, hdepth);
      target.xyz = H;
      target.w = 1;
    }
  }

  if(target.w > 0) {
    force += (target.xyz - pos) * 0.5;
  }

  // damping
  vel *= 0.95;

  // accelerate
  vel += elapsed * force;

  // move
  pos += elapsed * vel;

  posOut = vec4(pos, 1.0);
  velOut = vec4(vel, 0.0);
  misOut = vec4(thermo, age, 0, 0);
  tarOut = vec4(target);
}