realityplayground-of/zoneb/bin/data/shaders/particles/update.frag

#extension GL_ARB_explicit_attrib_location : enable

// ping pong inputs
uniform sampler2DRect particles0;
uniform sampler2DRect particles1;
uniform sampler2DRect particles2;
uniform sampler2DRect particles3;
uniform sampler2DRect particles4;
uniform sampler2DRect particles5;

uniform sampler2DRect   u_depth;
uniform sampler2DRect   u_world;
uniform sampler2DRect   u_v4l2cam;

uniform ivec2 uFrameSize;
uniform ivec2 uDepthFrameSize;

uniform vec3 mouse;
uniform float radiusSquared;
uniform float elapsed;
uniform float u_time;

uniform vec3 uHottest0;
uniform vec3 uHottest1;
uniform vec3 uHottest3d0;
uniform vec3 uHottest3d1;

in vec2 texCoordVarying;

layout(location = 0) out vec4 posOut;
layout(location = 1) out vec4 velOut;
layout(location = 2) out vec4 misOut;
layout(location = 3) out vec4 tarOut;
layout(location = 4) out vec4 prevPosOut;
layout(location = 5) out vec4 orgPosOut;


vec3 random3(vec3 c) {
	float j = 4096.0*sin(dot(c,vec3(17.0, 59.4, 15.0)));
	vec3 r;
	r.z = fract(512.0*j);
	j *= .125;
	r.x = fract(512.0*j);
	j *= .125;
	r.y = fract(512.0*j);
	return r-0.5;
}

/* skew constants for 3d simplex functions */
const float F3 =  0.3333333;
const float G3 =  0.1666667;

/* 3d simplex noise */
float simplex3d(vec3 p) {
	 /* 1. find current tetrahedron T and it's four vertices */
	 /* s, s+i1, s+i2, s+1.0 - absolute skewed (integer) coordinates of T vertices */
	 /* x, x1, x2, x3 - unskewed coordinates of p relative to each of T vertices*/
	 
	 /* calculate s and x */
	 vec3 s = floor(p + dot(p, vec3(F3)));
	 vec3 x = p - s + dot(s, vec3(G3));
	 
	 /* calculate i1 and i2 */
	 vec3 e = step(vec3(0.0), x - x.yzx);
	 vec3 i1 = e*(1.0 - e.zxy);
	 vec3 i2 = 1.0 - e.zxy*(1.0 - e);
	 	
	 /* x1, x2, x3 */
	 vec3 x1 = x - i1 + G3;
	 vec3 x2 = x - i2 + 2.0*G3;
	 vec3 x3 = x - 1.0 + 3.0*G3;
	 
	 /* 2. find four surflets and store them in d */
	 vec4 w, d;
	 
	 /* calculate surflet weights */
	 w.x = dot(x, x);
	 w.y = dot(x1, x1);
	 w.z = dot(x2, x2);
	 w.w = dot(x3, x3);
	 
	 /* w fades from 0.6 at the center of the surflet to 0.0 at the margin */
	 w = max(0.6 - w, 0.0);
	 
	 /* calculate surflet components */
	 d.x = dot(random3(s), x);
	 d.y = dot(random3(s + i1), x1);
	 d.z = dot(random3(s + i2), x2);
	 d.w = dot(random3(s + 1.0), x3);
	 
	 /* multiply d by w^4 */
	 w *= w;
	 w *= w;
	 d *= w;
	 
	 /* 3. return the sum of the four surflets */
	 return dot(d, vec4(52.0));
}

/* const matrices for 3d rotation */
const mat3 rot1 = mat3(-0.37, 0.36, 0.85,-0.14,-0.93, 0.34,0.92, 0.01,0.4);
const mat3 rot2 = mat3(-0.55,-0.39, 0.74, 0.33,-0.91,-0.24,0.77, 0.12,0.63);
const mat3 rot3 = mat3(-0.71, 0.52,-0.47,-0.08,-0.72,-0.68,-0.7,-0.45,0.56);

/* directional artifacts can be reduced by rotating each octave */
float simplex3d_fractal(vec3 m) {
    return   0.5333333*simplex3d(m*rot1)
			+0.2666667*simplex3d(2.0*m*rot2)
			+0.1333333*simplex3d(4.0*m*rot3)
			+0.0666667*simplex3d(8.0*m);
}

void main()
{
  vec3 pos = texture(particles0, texCoordVarying.st).xyz;
  vec3 vel = texture(particles1, texCoordVarying.st).xyz;
  vec3 misc = texture(particles2, texCoordVarying.st).xyz;
  vec4 target = texture(particles3, texCoordVarying.st).xyzw;
  vec3 prevPos = pos;//texture(particles4, texCoordVarying.st).xyz;

  float fraction = 8;
  float thermo = texture2D(u_v4l2cam, texCoordVarying.st/fraction).r;

  vec2 subPix = mod(texCoordVarying.st / fraction, 1.0);
  vec2 basePix = texCoordVarying.st/fraction - subPix;
  float depth00 = texture(u_depth, basePix + vec2(0, 0)).x;
  float depth01 = texture(u_depth, basePix + vec2(0, 1)).x;
  float depth10 = texture(u_depth, basePix + vec2(1, 0)).x;
  float depth11 = texture(u_depth, basePix + vec2(1, 1)).x;
  vec4 ray00 = texture(u_world, basePix + vec2(0, 0));
  vec4 ray01 = texture(u_world, basePix + vec2(0, 1));
  vec4 ray10 = texture(u_world, basePix + vec2(1, 0));
  vec4 ray11 = texture(u_world, basePix + vec2(1, 1));

  float depth0 = mix(depth00, depth10, subPix.x);
  float depth1 = mix(depth01, depth11, subPix.x);
  vec4 ray0 = mix(ray00, ray10, subPix.x);
  vec4 ray1 = mix(ray01, ray11, subPix.x);

  float depth = mix(depth0, depth1, subPix.y);
  vec4 ray = mix(ray0, ray1, subPix.y);

  float vValid = (depth00 != 0 && depth01 != 0 && depth10 != 0 && depth11 != 0 && ray.x != 0 && ray.y != 0) ? 1 : 0;

  vec4 posWorld = vec4(1);
  posWorld.z = -depth * 65535.0; // Remap to float range.
  posWorld.x = ray.x * posWorld.z;
  posWorld.y = ray.y * posWorld.z;
  posWorld.xyz += random3(posWorld.xyz) * 0.3;

  float age = misc.y;
  if(age > 1) { // reached target
    if(vValid == 1) { // rebirth if point is valid
    target.w = 0;
      age = 0;
    }
  }

  if(vValid == 1 && target.w == 0) { // point valid && no target -> move to the point
    pos = posWorld.xyz;
    // prevPos = posWorld.xyz;// + vec3(1,0,0);//random3(posWorld.xyz) * 0.5;
    age = 0;
  }
  else if (target.w > 0) { // targeted
    age += 0.005;
    thermo = misc.x;
  }
  else { // wandering
    age += 0.1;
    thermo = misc.x;
  }

  if(vValid == 1 && target.w > 0 && length(target.xy - pos.xy) < 100) { // arrived
    age += 0.04;
  }

  // wandering
  vec3 force = vec3(0,0,0);
  if(vValid == 1 && target.w == 0) {
    float th = 3.1415 * 4 * simplex3d_fractal(vec3(pos.xyz * 0.0001));
    float phi = 3.1415 * simplex3d_fractal(pos.xyz * 0.0002);
    force.x += cos(th) * cos(phi);
    force.y += sin(th) * cos(phi);
    force.z += sin(phi);
    force *= 100;
  }
  else {
    float th = 3.1415 * 4 * simplex3d_fractal(vec3(pos.xyz * 0.01));
    float phi = 3.1415 * simplex3d_fractal(pos.xyz * 0.02);
    force.x += cos(th) * cos(phi);
    force.y += sin(th) * cos(phi);
    force.z += sin(phi);
    force *= 100;
  }

  int trapped = 0;
  if(age < 0.001) { // targetting
    target.w = 0;
    if(mod(u_time*0.1+simplex3d_fractal(vec3(texCoordVarying,u_time)),1) > length(texCoordVarying.st/fraction - uHottest0.st + mod(random3(pos).xy, 8)-vec2(4))/10) {
      vec2 h = uHottest1.st;
      vec4 hray = texture(u_world, h);
      float hdepth = -depth * 65535.0;
      if(hdepth == 0) hdepth = -0.01 * 65535.0;
      vec3 H = vec3(hray.xy * hdepth, hdepth);
      target.xyz = H + random3(pos) * 3;
      target.w = 1;
      thermo += random3(pos).y * 0.2 - 0.1;

      if(mod(random3(pos).x,1) > 0.05) {
        trapped = 1;
      }
    }
    else if(mod(u_time*0.1+simplex3d_fractal(vec3(texCoordVarying,u_time)),1) > length(texCoordVarying.st/fraction - uHottest1.st + mod(random3(pos).xy, 8)-vec2(4))/10) {
      vec2 h = uHottest0.st;
      vec4 hray = texture(u_world, h);
      float hdepth = -depth * 65535.0;
      if(hdepth == 0) hdepth = -0.01 * 65535.0;
      vec3 H = vec3(hray.xy * hdepth, hdepth);
      target.xyz = H + random3(pos) * 3;
      target.w = 1;
      thermo += random3(pos).y * 0.2 - 0.1;

      if(mod(random3(pos).x,1) > 0.05) {
        trapped = 1;
      }
    }
    age = 0.001;
  }


  if(target.w > 0) { // go to target
    float th = atan(-pos.y + target.y, -pos.x + target.x);
    float phi = atan(-pos.z + target.z, length(target.xy-pos.xy));
    th += 3.1415 * 1 * simplex3d_fractal(vec3(pos.xyz * 0.01) + vec3(u_time, 0, 0));
    phi += 3.1415 * 1 * simplex3d_fractal(pos.xyz * 0.01);
    force.x = cos(th) * cos(phi);
    force.y = sin(th) * cos(phi);
    force.z = sin(phi);
    force *= 100 + 300 * simplex3d_fractal(vec3(texCoordVarying, 0.0));

    // if(trapped == 1) {
    //   target.w = 0;
    // }
  }

  // damping
  vel *= 0.95;

  // accelerate
  vel += elapsed * force;

  // move
  prevPos = pos;
  // if(length(pos - posWorld.xyz) < 300) {
  //   prevPos = posWorld.xyz;
  // }
  pos += elapsed * vel;

  posOut = vec4(pos, 1.0);
  velOut = vec4(vel, 0.0);
  misOut = vec4(thermo, age, 0, 0);
  tarOut = vec4(target);
  prevPosOut = vec4(prevPos, 1.0);
  orgPosOut = posWorld;
}